Grammalecte  Diff

    ({w1})([.],)  @@0,$
        <<- not re.search("^(?:etc|[A-Z]|fig|hab|litt|circ|coll|ref|étym|suppl|bibl|bibliogr|cit|vol|déc|nov|oct|janv|juil|avr|sept|pp?)$", \1)
        -2>> ,|.                                                            && Pas de virgule après un point (sauf éventuellement après une abréviation).

TEST: ceci, cela{{, …}}                                                   ->> …
TEST: Les chiens, les chats{{.,}} les poules.                             ->> ,|.


# Fin de paragraphe
#__<i>/typo__  ({w_2}) *$   @@0
#    <<- before("[a-zéàùèê][.] ") and not before("^(?:\\d|\w[.])")
#    -1>> \1.|\1…|\1 !|\1 ?|\1 :|\1 ;|\1,                                               && Il manque une ponctuation finale.


!!

__[s]/typo(typo_math)__
    (?:cos|sin|tan|cotan|log|ln)²? [2-9]?[a-zA-Zα-ωΑ-Ω]
        <<- ->> =\0.replace(" ", "(")+")|"+\0.replace(" ", " ")             && Mettez des parenthèses (ou éventuellement un espace insécable).

TEST: {{cos ω}}                                         ->> cos(ω)|cos ω
TEST: {{sin γ}}                                         ->> sin(γ)|sin γ


#__[s]/virg(virg_nombre)__
#    [0-9]+[.]([0-9]+)(?![,.])
#        <<-  ->> =\0.replace(".", ",")                     && En français, le séparateur décimal est la virgule, non le point.
#
#TEST: +{{1.5}} dioptrie
#TEST: j’en veux 2.000
#TEST: et moi 3.000.000 de dollars


!!
!!
!!!! Tirets                                                                                       !!
!!
!!

    tout [mes|tes|ses|ces|nos|vos|leurs|ceux|celles]
        <<- /gn/ not morph(<1, ">(?:d[eu]|avant|après|malgré)/") -1>> tous                          && Erreur d’accord probable avec « \2 ».

    tout les @:¬:(?:3s|Oo)
        <<- /gn/ not morph(<1, ">(?:d[eu]|avant|après|malgré)/") -1>> tous                          && Erreur d’accord probable avec « les \3 ».

    de tout les temps
        <<- /gn/ -2>> tous                                                                          && Erreur d’accord avec « \3 \4 ».

TEST: {{Tout}} deux sont partis les premiers.
TEST: {{Tout}} mes hommes sont venus.
TEST: {{Tout}} les hommes sont dingues.
TEST: Donne à manger à {{tout}} ceux qui sont là.
TEST: le meilleur hamburger de {{tout}} les temps
TEST: Revenus de tout ceux qui sont partis ont perdu la foi.
TEST: car malgré tout ceux qui persistent obtiennent parfois justice.
TEST: je ne connais pas du tout ceux dont tu parles.
TEST: Malgré tout ces hommes sont quand même revenus.
TEST: Les tout premiers hommes.
TEST: Les tout petits ne sont pas des légumes.
TEST: Faire des envois par tout petits nombres.


__gn_toute_det__
    toute [celles|les|des|mes|tes|ses|ces]
        <<- /gn/ -1>> toutes                                                                        && Erreur d’accord probable avec “\2”.

    toute [ce|cet]
        <<- /gn/ -1>> tout                                                                          && Erreur d’accord probable avec “\2”.

    toute mon ~^[bcdfgjklmnpqrstvwxz]
        <<- /gn/ -1>> tout                                                                          && Erreur d’accord probable avec “\2”.

    [<start>|,|(|/_start_]  toute  [ne|n’|me|m’|te|t’|se|s’]
    [<start>|,|(|/_start_]  toute  @:[123]p
        <<- /gn/ -2>> toutes                                                                        && Si vous voulez dire “tous” au féminin, écrivez “toutes”.

TEST: {{Toute}} celles qui viendront…
TEST: et {{toute}} ce barouf ne nous a apporté que des ennuis.
TEST: car {{toute}} mon savoir vient d’elle
TEST: {{toute}} prenaient le train
TEST: {{toute}} m’ennuyaient
TEST: toute mon ignorance
TEST: j’eus toutes les peines du monde à l’en convaincre


__gn_tous_det_nom__
    [<start>|,|(]     tous    [des|mes|tes|ses|ces]   @:[NA].*:f¬:[me]
    [<start>|,|(]     tous    [les]                   @:[NA].*:f¬:(?:3p|[me]|Y)
        <<- /gn/ -2>> toutes                                                                        && Erreur d’accord probable : « \4 » est féminin.
        <<- /gn/ __also__ and hasFemForm(\4) -4>> =suggMasPlur(\4, True)                            && Erreur d’accord probable : « \2 » est masculin.

    tous    [des|mes|tes|ses|ces]   @:[NA].*:f¬:[me]
    tous    [les]                   @:[NA].*:f¬:(?:3p|[me]|Y)
        <<- /gn/ morph(<1, ":", ":(?:R|[123][sp]|Q)|>(?:[nv]ous|eux)/") -1>> toutes                 && Erreur d’accord probable : « \3 » est féminin.
        <<- /gn/ __also__ and hasFemForm(\3) -3>> =suggMasPlur(\3, True)                            && Erreur d’accord probable : « \1 » est masculin.

    tous un chacun
        <<- /loc/ ->> tout un chacun                                                                && Pronom indéfini “tout un chacun”.|https://fr.wiktionary.org/wiki/tout_un_chacun

    [<start>|(] tous [le|l’|ce|cet|mon|ton|son|notre|votre|leur] @:N.*:[me]:[si]
    [<start>|(] tous [le|l’|ce|cet|mon|ton|son|notre|votre|leur] @:N.*:[me]:[si]
        <<- /gn/ -2>> tout                                                                          && Erreur d’accord probable avec « \3 \4 ».

TEST: {{tous}} ces {{idiotes}}
TEST: indubitablement {{tous}} des {{privilégiées}}
TEST: {{tous un chacun}} avait son opinion
TEST: {{tous}} mon amour pour elle n’y fit rien
TEST: {{tous}} mon plan consistait à les prendre par surprise et de vitesse
TEST: ça consiste à ne pas tous les lire
TEST: Ils ont tous mon plan de sauvetage de Beyrouth.
TEST: il y avait pour tous une carte de bienvenue, pour toutes un bouquet de rose.
TEST: ils avaient tous le même bagage, tous le dessein de vaincre


__gn_toutes_det_nom__
    [<start>|,|(]     toutes  [des|mes|tes|ses|ces]   @:[NA].*:m¬:[fe]
    [<start>|,|(]     toutes  [les]                   @:[NA].*:m¬:(?:3p|[fe]|Y)
        <<- /gn/ -2>> tous                                                                          && Erreur d’accord probable : « \4 » est masculin.
        <<- /gn/ __also__ and hasFemForm(\4) -4>> =suggFemPlur(\4, True)                            && Erreur d’accord probable : « \2 » est féminin.

    toutes  [des|mes|tes|ses|ces]   @:[NA].*:m¬:[fe]
    toutes  [les]                   @:[NA].*:m¬:(?:3p|[fe]|Y)
        <<- /gn/ morph(<1, ":", ":(?:R|[123][sp]|Q)|>(?:[nv]ous|eux)/") -1>> tous                   && Erreur d’accord probable : « \3 » est masculin.
        <<- /gn/ __also__ and hasFemForm(\3) -3>> =suggFemPlur(\3, True)                            && Erreur d’accord probable : « \1 » est féminin.

    [<start>|(] toutes [la|l’|cette|mon|ton|son|ma|ta|sa|notre|votre|leur] @:N.*:[fe]:[si]
    [<start>|(] toutes [la|l’|cette|mon|ton|son|ma|ta|sa|notre|votre|leur] @:N.*:[fe]:[si]
        <<- /gn/ -2>> toute                                                                         && Erreur d’accord probable avec « \3 \4 ».

TEST: {{toutes}} mes {{bars}}
TEST: vraiment {{toutes}} des {{costauds}}
TEST: {{toutes}} sa dévotion n’y suffisait pas                                          ->> toute
TEST: {{toutes}} la pensée philosophique a buté sur la question de la liberté           ->> toute
TEST: Elles connaissent toutes le monde féerique des princes et princesses.
TEST: Les filles, plus studieuses que les garçons, ont toutes le document transmis par courriel.
TEST: elles avaient toutes la même idée, toutes la même ambition, toutes l’obsession du succès


__gn_tout_nom__
    [<start>|,|(] tout  @:N.*:[fp]¬:(?:A|W|G|M|Y|[me]:[is]|3s)
    de          tout  @:N.*:[fp]¬:(?:A|W|G|M|Y|[me]:[is]|3s)
        <<- /gn/ -3>> =suggMasSing(\3, True)                                                        && Accord avec “tout” : “\3” devrait être au masculin singulier.